[ Index ]

PHP Cross Reference of Unnamed Project

title

Body

[close]

/se3-unattended/var/se3/unattended/install/linuxaux/opt/perl/lib/5.10.0/ExtUtils/MakeMaker/ -> FAQ.pod (source)

   1  package ExtUtils::MakeMaker::FAQ;
   2  
   3  use vars qw($VERSION);
   4  $VERSION = '1.12';
   5  
   6  1;
   7  __END__
   8  
   9  =head1 NAME
  10  
  11  ExtUtils::MakeMaker::FAQ - Frequently Asked Questions About MakeMaker
  12  
  13  =head1 DESCRIPTION
  14  
  15  FAQs, tricks and tips for C<ExtUtils::MakeMaker>.
  16  
  17  
  18  =head2 Module Installation
  19  
  20  =over 4
  21  
  22  =item How do I install a module into my home directory?
  23  
  24  If you're not the Perl administrator you probably don't have
  25  permission to install a module to its default location.  Then you
  26  should install it for your own use into your home directory like so:
  27  
  28      # Non-unix folks, replace ~ with /path/to/your/home/dir
  29      perl Makefile.PL INSTALL_BASE=~
  30  
  31  This will put modules into F<~/lib/perl5>, man pages into F<~/man> and
  32  programs into F<~/bin>.
  33  
  34  To ensure your Perl programs can see these newly installed modules,
  35  set your C<PERL5LIB> environment variable to F<~/lib/perl5> or tell
  36  each of your programs to look in that directory with the following:
  37  
  38      use lib "$ENV{HOME}/lib/perl5";
  39  
  40  or if $ENV{HOME} isn't set and you don't want to set it for some
  41  reason, do it the long way.
  42  
  43      use lib "/path/to/your/home/dir/lib/perl5";
  44  
  45  
  46  =item How do I get MakeMaker and Module::Build to install to the same place?
  47  
  48  Module::Build, as of 0.28, supports two ways to install to the same
  49  location as MakeMaker.
  50  
  51  1) Use INSTALL_BASE / C<--install_base>
  52  
  53  MakeMaker (as of 6.31) and Module::Build (as of 0.28) both can install
  54  to the same locations using the "install_base" concept.  See
  55  L<ExtUtils::MakeMaker/INSTALL_BASE> for details.  To get MM and MB to
  56  install to the same location simply set INSTALL_BASE in MM and
  57  C<--install_base> in MB to the same location.
  58  
  59      perl Makefile.PL INSTALL_BASE=/whatever
  60      perl Build.PL    --install_base /whatever
  61  
  62  2) Use PREFIX / C<--prefix>
  63  
  64  Module::Build 0.28 added support for C<--prefix> which works like
  65  MakeMaker's PREFIX.
  66  
  67      perl Makefile.PL PREFIX=/whatever
  68      perl Build.PL    --prefix /whatever
  69  
  70  
  71  =item How do I keep from installing man pages?
  72  
  73  Recent versions of MakeMaker will only install man pages on Unix like
  74  operating systems.
  75  
  76  For an individual module:
  77  
  78          perl Makefile.PL INSTALLMAN1DIR=none INSTALLMAN3DIR=none
  79  
  80  If you want to suppress man page installation for all modules you have
  81  to reconfigure Perl and tell it 'none' when it asks where to install
  82  man pages.
  83  
  84  
  85  =item How do I use a module without installing it?
  86  
  87  Two ways.  One is to build the module normally...
  88  
  89          perl Makefile.PL
  90          make
  91          make test
  92  
  93  ...and then set the PERL5LIB environment variable to point at the
  94  blib/lib and blib/arch directories.
  95  
  96  The other is to install the module in a temporary location.
  97  
  98          perl Makefile.PL INSTALL_BASE=~/tmp
  99          make
 100          make test
 101          make install
 102  
 103  And then set PERL5LIB to F<~/tmp/lib/perl5>.  This works well when you
 104  have multiple modules to work with.  It also ensures that the module
 105  goes through its full installation process which may modify it.
 106  
 107  =item PREFIX vs INSTALL_BASE from Module::Build::Cookbook
 108  
 109  The behavior of PREFIX is complicated and depends closely on how your
 110  Perl is configured. The resulting installation locations will vary from
 111  machine to machine and even different installations of Perl on the same machine.
 112  Because of this, its difficult to document where prefix will place your modules.
 113  
 114  In contrast, INSTALL_BASE has predictable, easy to explain installation locations.
 115  Now that Module::Build and MakeMaker both have INSTALL_BASE there is little reason
 116  to use PREFIX other than to preserve your existing installation locations. If you
 117  are starting a fresh Perl installation we encourage you to use INSTALL_BASE. If
 118  you have an existing installation installed via PREFIX, consider moving it to an
 119  installation structure matching INSTALL_BASE and using that instead.
 120  
 121  =back
 122  
 123  
 124  =head2 Philosophy and History
 125  
 126  =over 4
 127  
 128  =item Why not just use <insert other build config tool here>?
 129  
 130  Why did MakeMaker reinvent the build configuration wheel?  Why not
 131  just use autoconf or automake or ppm or Ant or ...
 132  
 133  There are many reasons, but the major one is cross-platform
 134  compatibility.
 135  
 136  Perl is one of the most ported pieces of software ever.  It works on
 137  operating systems I've never even heard of (see perlport for details).
 138  It needs a build tool that can work on all those platforms and with
 139  any wacky C compilers and linkers they might have.
 140  
 141  No such build tool exists.  Even make itself has wildly different
 142  dialects.  So we have to build our own.
 143  
 144  
 145  =item What is Module::Build and how does it relate to MakeMaker?
 146  
 147  Module::Build is a project by Ken Williams to supplant MakeMaker.
 148  Its primary advantages are:
 149  
 150  =over 8
 151  
 152  =item * pure perl.  no make, no shell commands
 153  
 154  =item * easier to customize
 155  
 156  =item * cleaner internals
 157  
 158  =item * less cruft
 159  
 160  =back
 161  
 162  Module::Build is the official heir apparent to MakeMaker and we
 163  encourage people to work on M::B rather than spending time adding features
 164  to MakeMaker.
 165  
 166  =back
 167  
 168  
 169  =head2 Module Writing
 170  
 171  =over 4
 172  
 173  =item How do I keep my $VERSION up to date without resetting it manually?
 174  
 175  Often you want to manually set the $VERSION in the main module
 176  distribution because this is the version that everybody sees on CPAN
 177  and maybe you want to customize it a bit.  But for all the other
 178  modules in your dist, $VERSION is really just bookkeeping and all that's
 179  important is it goes up every time the module is changed.  Doing this
 180  by hand is a pain and you often forget.
 181  
 182  Simplest way to do it automatically is to use your version control
 183  system's revision number (you are using version control, right?).
 184  
 185  In CVS, RCS and SVN you use $Revision$ (see the documentation of your
 186  version control system for details).  Every time the file is checked
 187  in the $Revision$ will be updated, updating your $VERSION.
 188  
 189  SVN uses a simple integer for $Revision$ so you can adapt it for your
 190  $VERSION like so:
 191  
 192      ($VERSION) = q$Revision$ =~ /(\d+)/;
 193  
 194  In CVS and RCS version 1.9 is followed by 1.10.  Since CPAN compares
 195  version numbers numerically we use a sprintf() to convert 1.9 to 1.009
 196  and 1.10 to 1.010 which compare properly.
 197  
 198      $VERSION = sprintf "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/g;
 199  
 200  If branches are involved (ie. $Revision: 1.5.3.4$) its a little more
 201  complicated.
 202  
 203      # must be all on one line or MakeMaker will get confused.
 204      $VERSION = do { my @r = (q$Revision$ =~ /\d+/g); sprintf "%d."."%03d" x $#r, @r };
 205  
 206  In SVN, $Revision$ should be the same for every file in the project so
 207  they would all have the same $VERSION.  CVS and RCS have a different
 208  $Revision$ per file so each file will have a differnt $VERSION.
 209  Distributed version control systems, such as SVK, may have a different
 210  $Revision$ based on who checks out the file leading to a different $VERSION
 211  on each machine!  Finally, some distributed version control systems, such
 212  as darcs, have no concept of revision number at all.
 213  
 214  
 215  =item What's this F<META.yml> thing and how did it get in my F<MANIFEST>?!
 216  
 217  F<META.yml> is a module meta-data file pioneered by Module::Build and
 218  automatically generated as part of the 'distdir' target (and thus
 219  'dist').  See L<ExtUtils::MakeMaker/"Module Meta-Data">.
 220  
 221  To shut off its generation, pass the C<NO_META> flag to C<WriteMakefile()>.
 222  
 223  
 224  =item How do I delete everything not in my F<MANIFEST>?
 225  
 226  Some folks are surpried that C<make distclean> does not delete
 227  everything not listed in their MANIFEST (thus making a clean
 228  distribution) but only tells them what they need to delete.  This is
 229  done because it is considered too dangerous.  While developing your
 230  module you might write a new file, not add it to the MANIFEST, then
 231  run a C<distclean> and be sad because your new work was deleted.
 232  
 233  If you really want to do this, you can use
 234  C<ExtUtils::Manifest::manifind()> to read the MANIFEST and File::Find
 235  to delete the files.  But you have to be careful.  Here's a script to
 236  do that.  Use at your own risk.  Have fun blowing holes in your foot.
 237  
 238      #!/usr/bin/perl -w
 239      
 240      use strict;
 241      
 242      use File::Spec;
 243      use File::Find;
 244      use ExtUtils::Manifest qw(maniread);
 245      
 246      my %manifest = map  {( $_ => 1 )}
 247                     grep { File::Spec->canonpath($_) }
 248                          keys %{ maniread() };
 249  
 250      if( !keys %manifest ) {
 251          print "No files found in MANIFEST.  Stopping.\n";
 252          exit;
 253      }
 254      
 255      find({
 256            wanted   => sub {
 257                my $path = File::Spec->canonpath($_);
 258      
 259                return unless -f $path;
 260                return if exists $manifest{ $path };
 261      
 262                print "unlink $path\n";
 263                unlink $path;
 264            },
 265            no_chdir => 1
 266           },
 267           "."
 268      );
 269  
 270  
 271  =back
 272  
 273  =head2 XS
 274  
 275  =over 4
 276  
 277  =item How to I prevent "object version X.XX does not match bootstrap parameter Y.YY" errors?
 278  
 279  XS code is very sensitive to the module version number and will
 280  complain if the version number in your Perl module doesn't match.  If
 281  you change your module's version # without rerunning Makefile.PL the old
 282  version number will remain in the Makefile causing the XS code to be built
 283  with the wrong number.
 284  
 285  To avoid this, you can force the Makefile to be rebuilt whenever you
 286  change the module containing the version number by adding this to your
 287  WriteMakefile() arguments.
 288  
 289      depend => { '$(FIRST_MAKEFILE)' => '$(VERSION_FROM)' }
 290  
 291  
 292  =item How do I make two or more XS files coexist in the same directory?
 293  
 294  Sometimes you need to have two and more XS files in the same package.
 295  One way to go is to put them into separate directories, but sometimes
 296  this is not the most suitable solution. The following technique allows
 297  you to put two (and more) XS files in the same directory.
 298  
 299  Let's assume that we have a package C<Cool::Foo>, which includes
 300  C<Cool::Foo> and C<Cool::Bar> modules each having a separate XS
 301  file. First we use the following I<Makefile.PL>:
 302  
 303    use ExtUtils::MakeMaker;
 304  
 305    WriteMakefile(
 306        NAME        => 'Cool::Foo',
 307        VERSION_FROM    => 'Foo.pm',
 308        OBJECT              => q/$(O_FILES)/,
 309        # ... other attrs ...
 310    );
 311  
 312  Notice the C<OBJECT> attribute. MakeMaker generates the following
 313  variables in I<Makefile>:
 314  
 315    # Handy lists of source code files:
 316    XS_FILES= Bar.xs \
 317        Foo.xs
 318    C_FILES = Bar.c \
 319        Foo.c
 320    O_FILES = Bar.o \
 321        Foo.o
 322  
 323  Therefore we can use the C<O_FILES> variable to tell MakeMaker to use
 324  these objects into the shared library.
 325  
 326  That's pretty much it. Now write I<Foo.pm> and I<Foo.xs>, I<Bar.pm>
 327  and I<Bar.xs>, where I<Foo.pm> bootstraps the shared library and
 328  I<Bar.pm> simply loading I<Foo.pm>.
 329  
 330  The only issue left is to how to bootstrap I<Bar.xs>. This is done
 331  from I<Foo.xs>:
 332  
 333    MODULE = Cool::Foo PACKAGE = Cool::Foo
 334  
 335    BOOT:
 336    # boot the second XS file
 337    boot_Cool__Bar(aTHX_ cv);
 338  
 339  If you have more than two files, this is the place where you should
 340  boot extra XS files from.
 341  
 342  The following four files sum up all the details discussed so far.
 343  
 344    Foo.pm:
 345    -------
 346    package Cool::Foo;
 347  
 348    require DynaLoader;
 349  
 350    our @ISA = qw(DynaLoader);
 351    our $VERSION = '0.01';
 352    bootstrap Cool::Foo $VERSION;
 353  
 354    1;
 355  
 356    Bar.pm:
 357    -------
 358    package Cool::Bar;
 359  
 360    use Cool::Foo; # bootstraps Bar.xs
 361  
 362    1;
 363  
 364    Foo.xs:
 365    -------
 366    #include "EXTERN.h"
 367    #include "perl.h"
 368    #include "XSUB.h"
 369  
 370    MODULE = Cool::Foo  PACKAGE = Cool::Foo
 371  
 372    BOOT:
 373    # boot the second XS file
 374    boot_Cool__Bar(aTHX_ cv);
 375  
 376    MODULE = Cool::Foo  PACKAGE = Cool::Foo  PREFIX = cool_foo_
 377  
 378    void
 379    cool_foo_perl_rules()
 380  
 381        CODE:
 382        fprintf(stderr, "Cool::Foo says: Perl Rules\n");
 383  
 384    Bar.xs:
 385    -------
 386    #include "EXTERN.h"
 387    #include "perl.h"
 388    #include "XSUB.h"
 389  
 390    MODULE = Cool::Bar  PACKAGE = Cool::Bar PREFIX = cool_bar_
 391  
 392    void
 393    cool_bar_perl_rules()
 394  
 395        CODE:
 396        fprintf(stderr, "Cool::Bar says: Perl Rules\n");
 397  
 398  And of course a very basic test:
 399  
 400    t/cool.t:
 401    --------
 402    use Test;
 403    BEGIN { plan tests => 1 };
 404    use Cool::Foo;
 405    use Cool::Bar;
 406    Cool::Foo::perl_rules();
 407    Cool::Bar::perl_rules();
 408    ok 1;
 409  
 410  This tip has been brought to you by Nick Ing-Simmons and Stas Bekman.
 411  
 412  =back
 413  
 414  =head1 PATCHING
 415  
 416  If you have a question you'd like to see added to the FAQ (whether or
 417  not you have the answer) please send it to makemaker@perl.org.
 418  
 419  =head1 AUTHOR
 420  
 421  The denizens of makemaker@perl.org.
 422  
 423  =head1 SEE ALSO
 424  
 425  L<ExtUtils::MakeMaker>
 426  
 427  =cut


Generated: Tue Mar 17 22:47:18 2015 Cross-referenced by PHPXref 0.7.1